Belajar Naskah

1. Halo, dunia!

Program adalah daftar perintah untuk komputer. Komputer mengerjakannya satu per satu, dari atas ke bawah.

Perintah pertama kita adalah tulis. Ia menampilkan sesuatu di Keluaran.

tulis("Halo, dunia!")

Tulisan ditaruh di antara tanda kutip. Kita boleh memakai tulis berkali-kali.

tulis("Namaku Naskah.")
tulis("Aku suka belajar.")
tulis("Kamu juga, kan?")

Dua garis miring // dipakai untuk catatan. Komputer tidak membacanya, jadi catatan hanya untuk manusia.

// Ini catatan untuk manusia
tulis("Halo!") // ini juga catatan

2. Menyimpan nilai

Kadang kita ingin mengingat sesuatu. Untuk itu ada variabel, yaitu kotak kecil yang diberi nama. Kita membuatnya dengan misal.

misal nama = "Budi"
misal umur = 9
tulis(nama)
tulis(umur)

Isi kotak bisa dimasukkan ke dalam tulisan dengan kurung kurawal { }.

misal nama = "Budi"
misal umur = 9
tulis("Halo, {nama}!")
tulis("Umurmu {umur} tahun.")

Isi kotak boleh diganti. Tulis namanya lagi, tanpa misal.

misal skor = 0
tulis("Skor: {skor}")
skor = 10
tulis("Skor sekarang: {skor}")

Kalau isinya tidak boleh berubah, pakai konstan. Di Indonesia angka desimal ditulis dengan koma, dan di Naskah juga: 3,14.

konstan pi = 3,14
tulis("Pi kira-kira {pi}")

Nama kotak diawali huruf kecil, misalnya skor atau namaTeman.

3. Berhitung

Komputer pandai berhitung. Tanda + artinya tambah, - kurang, * kali, dan / bagi.

tulis(5 + 3)
tulis(10 - 4)
tulis(6 * 7)
tulis(20 / 4)

Ada dua tanda lagi: % untuk sisa bagi dan ^ untuk pangkat.

tulis(17 % 5)
tulis(2 ^ 10)

Komputer mengerjakan kali dan bagi lebih dulu daripada tambah dan kurang, sama seperti di sekolah. Pakai kurung untuk mengubah urutannya.

tulis(2 + 3 * 4)
tulis((2 + 3) * 4)

Kita juga bisa berhitung dengan isi kotak.

misal panjang = 8
misal lebar = 5
misal luas = panjang * lebar
tulis("Luasnya {luas}")

Angka desimal memakai koma, dan tulisan bisa disambung dengan +.

tulis(10 / 4)
tulis(7,5 * 2)
tulis("Tinggiku " + 1,35 + " meter")

4. Mengambil keputusan

Komputer bisa memilih apa yang dikerjakan. Ia memeriksa sebuah syarat di sebelah jika. Kalau benar, ia mengerjakan isi pertama. Kalau tidak, ia mengerjakan isi lain.

misal nilai = 80
jika nilai >= 75 {
  tulis("Lulus!")
} lain {
  tulis("Belajar lagi, ya.")
}

Ini tanda-tanda untuk membandingkan: == sama dengan, != tidak sama dengan, < kurang dari, > lebih dari, <= kurang dari atau sama dengan, dan >= lebih dari atau sama dengan. Hati-hati: sama dengan memakai dua tanda sama dengan.

Syarat bisa digabung dengan dan, atau, dan bukan.

misal hari = "Sabtu"
jika hari == "Sabtu" atau hari == "Minggu" {
  tulis("Hore, libur!")
} lain {
  tulis("Ayo sekolah.")
}

misal umur = 10
jika umur >= 7 dan umur <= 12 {
  tulis("Kamu anak SD.")
}

Kalau pilihannya lebih dari dua, pakai lain jika.

misal nilai = 85
jika nilai >= 90 {
  tulis("Hebat sekali!")
} lain jika nilai >= 75 {
  tulis("Bagus!")
} lain {
  tulis("Ayo belajar lagi.")
}

5. Bertanya

Program bisa bertanya kepadamu. Perintahnya tanya. Program berhenti sebentar, menunggu jawabanmu, lalu melanjutkan.

misal nama = tanya("Siapa namamu?")
tulis("Halo, {nama}!")

Ketik jawabanmu di kotak yang muncul di Keluaran, lalu tekan Enter atau tombol Kirim. Jawabanmu disimpan di dalam kotak nama.

Jawaban selalu berupa tulisan. Kalau jawabanmu angka dan mau dihitung, ubah dulu dengan bilangan. Ia mengerti angka seperti 12, 1,5, dan 1.000.

misal umur = bilangan(tanya("Umurmu berapa?"))
tulis("Tahun depan kamu {umur + 1} tahun.")

Jawabanmu juga bisa dipakai untuk mengambil keputusan.

misal umur = bilangan(tanya("Umurmu berapa?"))
jika umur >= 7 {
  tulis("Kamu sudah bisa masuk SD.")
} lain {
  tulis("Sebentar lagi masuk SD, ya.")
}

Dua pertanyaan, lalu dihitung.

misal a = bilangan(tanya("Angka pertama?"))
misal b = bilangan(tanya("Angka kedua?"))
tulis("{a} + {b} = {a + b}")
tulis("{a} x {b} = {a * b}")

6. Mengulang

Komputer tidak pernah bosan. Kita bisa menyuruhnya mengulang. Cara pertama adalah mengulang dengan hitungan: untuk.

untuk i dari 1 sampai 5 {
  tulis("Putaran ke-{i}")
}

Nilai sampai ikut dihitung, jadi dari 1 sampai 5 ada lima putaran. Mari buat tabel perkalian 7.

untuk i dari 1 sampai 10 {
  tulis("7 x {i} = {7 * i}")
}

Untuk menghitung mundur, tambahkan langkah dengan angka negatif.

untuk i dari 5 sampai 1 langkah -1 {
  tulis(i)
}
tulis("Selesai!")

Cara kedua adalah selama: mengulang selama syaratnya masih benar.

misal angka = 1
selama angka <= 5 {
  tulis(angka)
  angka = angka + 1
}

Hati-hati! Kalau lupa mengubah angka, syaratnya tidak pernah menjadi salah dan ulangannya tidak pernah selesai. Di sini, program yang berjalan lebih dari 2 detik akan dihentikan.

7. Daftar

Daftar menyimpan banyak nilai sekaligus. Ia ditulis dengan kurung siku, nilainya dipisah koma dan spasi.

misal buah = ["apel", "jeruk", "mangga"]
tulis(buah)
tulis(buah.panjang)
tulis(buah[0])

panjang adalah banyaknya isi daftar. Nomor urutan mulai dari 0, jadi buah[0] adalah isi yang pertama.

Untuk menambah isi, pakai tambah. Untuk mengerjakan sesuatu pada setiap isi, pakai untuk setiap.

misal buah = ["apel", "jeruk"]
buah.tambah("mangga")
untuk setiap b dalam buah {
  tulis("Aku suka {b}")
}

Daftar angka bisa dijumlahkan.

misal nilai = [80, 90, 70]
misal jumlah = 0
untuk setiap n dalam nilai {
  jumlah = jumlah + n
}
tulis("Jumlah: {jumlah}")
tulis("Rata-rata: {jumlah / nilai.panjang}")

8. Membuat perintah sendiri

Kita bisa membuat perintah sendiri dengan fungsi. Perintah itu dibuat sekali, lalu dipakai sebanyak yang kita mau.

fungsi sapa(nama) {
  tulis("Halo, {nama}!")
}

sapa("Budi")
sapa("Ani")

Di dalam kurung ada bahan yang dibutuhkan perintah itu. Sebuah fungsi juga bisa memberi jawaban dengan hasilkan.

fungsi luas(panjang, lebar) {
  hasilkan panjang * lebar
}

tulis(luas(4, 5))
misal hasil = luas(3, 6)
tulis("Luasnya {hasil}")

Fungsi boleh dipakai di dalam syarat.

fungsi genap(n) {
  hasilkan n % 2 == 0
}

untuk i dari 1 sampai 6 {
  jika genap(i) {
    tulis("{i} genap")
  } lain {
    tulis("{i} ganjil")
  }
}

9. Benda dan cetakan

Hewan punya nama dan suara. Kita bisa membuat cetakan untuk hewan, lalu mencetak banyak hewan dari cetakan itu. Nama cetakan selalu diawali huruf kapital.

Hewan(nama) {
  .nama = nama

  suara() {
    hasilkan "..."
  }
}

misal burung = Hewan("Kiki")
tulis("{burung.nama} bilang {burung.suara()}")

.nama artinya nama milik benda ini sendiri. Cetakan boleh dipakai untuk membuat cetakan baru yang lebih khusus dengan turunan.

Hewan(nama) {
  .nama = nama

  suara() {
    hasilkan "..."
  }
}

Kucing(nama) turunan Hewan(nama) {
  suara() {
    hasilkan "meong"
  }
}

misal tom = Kucing("Tom")
tulis("{tom.nama} bilang {tom.suara()}")

Kucing punya suara sendiri yang menggantikan milik Hewan. Kalau mau memakai yang milik Hewan, tulis dua titik: ..suara().

Hewan(nama) {
  .nama = nama

  suara() {
    hasilkan "..."
  }
}

Kucing(nama) turunan Hewan(nama) {
  suara() {
    hasilkan "meong, bukan {..suara()}"
  }
}

tulis(Kucing("Tom").suara())

10. Kalau ada yang salah

Semua orang pernah salah menulis, termasuk pembuat program yang hebat. Komputer akan memberi tahu apa yang salah dan di baris berapa. Bacalah pelan-pelan, petunjuknya membantu.

Di sini ada huruf yang tertukar. Komputer menebak maksudmu.

misal nama = "Budi"
tulis(nmaa)

Angka desimal harus memakai koma, bukan titik.

misal tinggi = 1.35
tulis(tinggi)

Ada juga kesalahan yang baru ketahuan saat program berjalan. kosong artinya tidak ada isinya, jadi kita tidak bisa mengambil apa-apa darinya.

misal kotak = kosong
tulis("Mulai")
tulis(kotak.isi)

Kesalahan seperti itu bisa ditangani dengan coba dan tangkap, sehingga program tidak berhenti.

coba {
  misal kotak = kosong
  tulis(kotak.isi)
} tangkap galat {
  tulis("Ups: {galat.pesan}")
}
tulis("Programnya tetap jalan.")

11. Proyek kecil

Sekarang kamu bisa membuat program sendiri. Ini beberapa ide untuk dicoba dan diubah.

Daftar belanja dengan jumlah harganya.

misal barang = ["beras", "telur", "gula"]
misal harga = [12000, 28000, 15000]
misal total = 0
untuk i dari 0 sampai barang.panjang - 1 {
  tulis("{barang[i]}: {harga[i]}")
  total = total + harga[i]
}
tulis("Total: {total}")

Tabel perkalian dari 1 sampai 5.

untuk a dari 1 sampai 5 {
  untuk b dari 1 sampai 5 {
    tulis("{a} x {b} = {a * b}")
  }
}

Suara hewan dengan dua daftar.

misal hewan = ["kucing", "burung", "ikan"]
misal suara = ["meong", "cuit", "blub"]
untuk i dari 0 sampai 2 {
  tulis("{hewan[i]} bilang {suara[i]}")
}

Kartu nama dengan fungsi.

fungsi kartu(nama, umur, hobi) {
  tulis("Namaku {nama}.")
  tulis("Umurku {umur} tahun.")
  tulis("Aku suka {hobi}.")
}

kartu("Ani", 9, "menggambar")
kartu("Budi", 10, "bermain bola")

12. Lanjutan: menunggu

Komputer bisa disuruh menunggu. tunda menunggu sekian milidetik (1000 milidetik sama dengan 1 detik), dan tunggu menunggu sampai sebuah pekerjaan selesai.

fungsi hitungMundur() {
  untuk i dari 3 sampai 1 langkah -1 {
    tulis(i)
    tunggu tunda(400)
  }
  tulis("Selesai!")
}

tunggu hitungMundur()

Fungsi yang memakai tunggu otomatis berjalan sambil menunggu. Kamu tidak perlu menandainya.